禁書下載 | 禁書 - 禁書網

windows xp、win7、win8、office補丁批量安裝程序

兩個版本，一個可以安裝系統補丁和office補丁，一個比較簡單，只可以安裝系統補丁。
測試使用，如果有問題請反饋。

使用方法：下面代碼全選複製保存為hotfix.bat，補丁程序需要和這個批量安裝程序放在同一個目錄中。運行批量安裝代碼安裝。理論上應該可以支持全版本的系統，xp、win7、win8的補丁都可以使用這個批量安裝程序安裝。

這個補丁安裝批處理並沒有提供補丁下載，補丁下載需要在論壇的其它補丁下載地址貼中自行下載，然後集中放置到本批量安裝程序目錄中運行。
不是所有的補丁都可以批量安裝的，只有支持/quiet /norestart參數的補丁可以安裝。
vc++ .net等目前是不支持的。這些補丁也不多，所以手動安裝也可以。

目錄中是系統補丁就放置系統補丁，是office目標那麼就不要放置系統補丁，不要混放，目前沒有排錯設置，所以混放安裝會錯誤。

在win8 32系統下面，安裝補丁比較順利，兩個安裝代碼都沒有問題，第一個安裝代碼由於有安裝進度，感覺比較實用。這是因為安裝補丁的時間比較長，所以有進度顯示很方便。

代碼: 全選

@echo off
PUSHD %~dp0
color 0a
mode con lines=22
title 系統補丁批量安裝程序
If not exist *.exe (if not exist *.msu goto next2)
ver|find /i " 6." >nul||goto test
echo .>%windir%\test.txt
if exist %windir%\test.txt (
    del /f /q /a %windir%\test.txt>nul 2>nul
) else (
    cls
    echo.
    echo.
    echo    請右鍵◆以管理員身份運行◆本程序
    echo    按任意鍵退出...
    pause>nul
    exit
)
goto test2
:test
echo .>%windir%\test.txt
if exist %windir%\test.txt (
    del /f /q /a %windir%\test.txt>nul 2>nul
) else (
    cls
    echo.
    echo.
    echo    請以管理員身份登錄電腦運行本程序
    echo    按任意鍵退出...
    pause>nul
    exit
)
:test2
Set L1=　　　　　        　╭══════════════════╮
Set L2=　　　　        　　║　　　　　　　　　　　　　　　　　　║
Set L3=　　　        ╭══┤　      系統補丁批量安裝程序　      ├══╮
Set L4=　　        　║　　║　　　　　　　　　　　　　　　　　　║　　║
Set L5=　　　        ║　　╰══════════════════╯　　║
Set L6=　　　        ║　　　　　　　　　　　　　　　　　　　　　　　　║
Set L7=　　        　╟════════════════════════╢
Set L8=　　　        ║　    簡單         安全         易用            ║
Set L9=　　　        ╰────────────────────────╯
:begin
CLS
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo %L6%
Echo 　　　        ║　　[1] 安裝Windows補丁　 　　　　　　          ║
Echo 　　　        ║　　[2] 安裝Office2003補丁　　　　　            ║
Echo 　　　        ║　　[3] 安裝Office2007、2010、2013補丁　        ║
Echo 　　　        ║　　[0] 退出本程序　　　　　　　　　　　　      ║
Echo %L6%
Echo %L7%
Echo %L7%
Echo %L8%
Echo %L9%
echo.
echo.
set choice=
set /p choice=              選擇要進行的操作 (1/2/3/0) ，然後按回車：
If "%choice%"=="" goto begin
If not "%choice%"=="" Set Choice=%Choice:~0,1%
If /i "%choice%"=="1" goto GO2
If /i "%choice%"=="2" goto GO3
If /i "%choice%"=="3" goto GO4
If /i "%choice%"=="0" exit
goto begin

:GO2
set str1=
ver | find "6." > NUL && (set XT=Windows NT6&set CX=Windows*-KB*.msu&set str=/quiet /norestart&set str1=wusa&goto TOP)
ver | find "5." > NUL && (set XT=Windows NT5&set CX=Windows*-KB*.exe&set str=/quiet /norestart&goto TOP)
goto TOP

:GO3
set XT=Office2003
set CX=*.exe
set str=/q
goto TOP

:GO4
set XT=Office2007_2010_2013
set CX=*.exe
set str=/quiet /norestart
goto TOP

:TOP
set title=%XT% 補丁批量安裝程序
title %title%
set work=0
set no=0
set mo=0
set number=0
set hotfix=
set ko=▏
set kn=0
:Kong
if %kn% LSS 33 (set ko=%ko%　&set /a kn=%kn%+1&goto Kong)
for /F %%s in ('dir /b /a-d %CX% ^| find /v /c ""') do set all=%%s
for /F %%i in ('dir /b /a-d /OD %CX%') do (set hotfix=%%i&call :show)
set hotfix=&call :show
goto end
:show
if %number% GTR %mo% (
set num=%num%█
set /a mo=%mo%+1
set ko=%ko:~0,-1%
goto show
)
cls
echo.
echo.
if "%hotfix%"=="" (echo     %title% ) else (echo       正在安裝：%hotfix%)
echo                                                            進度： %no% / %all%
echo.&echo                                   已經完成 %work% %%%
echo     ┌──────────────────────────────────┐
echo     │%num%%ko%│&echo     │%num%%ko%│&echo     │%num%%ko%│
echo     └──────────────────────────────────┘
echo.
if %work%==100 goto :EOF
::ping -n 1 127.1 >nul
%str1% %hotfix% %str% >nul 2>nul
set /a no=%no%+1
set /a work=(%no%)*100/(%all%) 2>nul
set /a number=%work%/3
set /a number=%number%+1
goto :EOF

:end
echo       安裝完成，按任意鍵退出... （建議從新啟動系統）
pause>nul
exit

:next2
cls
echo.
echo.
echo    沒找到補丁程序
echo.
echo    補丁程序需要和批量安裝程序放在同一個文件夾內
echo.
echo    按任意鍵退出 ...
pause>nul&exit

第二個安裝代碼，比較簡單些，使用方法同上

代碼: 全選

@echo off
PUSHD %~dp0
color 0a
mode con lines=22
title 系統補丁批量安裝程序
setlocal enabledelayedexpansion
If not exist *.exe (if not exist *.msu goto next2)
ver|find /i " 6." >nul||goto test
echo .>%windir%\test.txt
if exist %windir%\test.txt (
    del /f /q /a %windir%\test.txt>nul 2>nul
) else (
    cls
    echo.
    echo.
    echo    請右鍵◆以管理員身份運行◆本程序
    echo    按任意鍵退出...
    pause>nul
    exit
)
goto test2
:test
echo .>%windir%\test.txt
if exist %windir%\test.txt (
    del /f /q /a %windir%\test.txt>nul 2>nul
) else (
    cls
    echo.
    echo.
    echo    請以管理員身份登錄電腦運行本程序
    echo    按任意鍵退出...
    pause>nul
    exit
)
:test2
ver | find "6." > NUL && (
for /f "delims=" %%i in ('dir /a-d /b /od Windows*-KB*.msu 2^>nul') do (
set str=%%i
echo.
echo.
echo     正在安裝 !str!
wusa !str! /quiet /norestart
cls
))

ver | find "5." > NUL && (
for /f "delims=" %%i in ('dir /a-d /b /od Windows*-KB*.exe 2^>nul') do (
set str=%%i
echo.
echo.
echo     正在安裝 !str!
!str! /quiet /norestart
cls
))
cls
echo.
echo.
echo       安裝完成，按任意鍵退出... （建議從新啟動系統）
pause>nul
exit

:next2
cls
echo.
echo.
echo    沒找到補丁程序
echo.
echo    補丁程序需要和批量安裝程序放在同一個文件夾內
echo.
echo    按任意鍵退出 ...
pause>nul
exit